PlatformIO_ESP32_ServoWebServer/MyIRemote/src/IRBedroom.cpp

#include <Arduino.h>
#include <IRrecv.h>
#include <IRsend.h>
#include <IRremoteESP8266.h>
#include <IRac.h>
#include <IRtext.h>
#include <IRutils.h>

#include <WiFi.h>
#include <PubSubClient.h>


const uint16_t kIrLed = 4;  // ESP8266 GPIO pin to use. Recommended: 4 (D2).
IRsend irsend(kIrLed);  // Set the GPIO to be used to sending the message.

// IR Receiver connected to PIN D5 (14)
const uint16_t kRecvPin = 14;
const uint32_t kBaudRate = 115200;
const uint16_t kCaptureBufferSize = 1024;
#if DECODE_AC
// Some A/C units have gaps in their protocols of ~40ms. e.g. Kelvinator
// A value this large may swallow repeats of some protocols
const uint8_t kTimeout = 50;
#else   // DECODE_AC
// Suits most messages, while not swallowing many repeats.
const uint8_t kTimeout = 15;
#endif  // DECODE_AC
const uint16_t kMinUnknownSize = 12;
#define LEGACY_TIMING_INFO false
IRrecv irrecv(kRecvPin, kCaptureBufferSize, kTimeout, true);
decode_results results;  // Somewhere to store the results


// Update these with values suitable for your network.
const char* ssid = "JoeNelsDarlings";
const char* password = "Paris2016";
const char* mqtt_server = "mqtt.ddns.kawomi.com";
const String room_name = "IRBedroom";
//const String room_name = "IRBedroom";

WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;
#define MSG_BUFFER_SIZE	(50)
char msg[MSG_BUFFER_SIZE];
int value = 0;

void setup_wifi() {

  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("X");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
 
  String recBuf="";
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    recBuf += (char)payload[i];
  }
  Serial.println(recBuf);

  int numEle=1;
  for (int i=0; i<recBuf.length() ; i++){
    if (recBuf.charAt(i) == ',') {
      numEle++;
    }
  }
  recBuf+=",";

  Serial.print("NumEle ");
  Serial.println(numEle);

  int rawPos=0;
  uint16_t rawData[numEle];
  String bufSingleNum="";
  for (int i=0;i<recBuf.length();i++){
    if (recBuf.charAt(i) != ',') {
      bufSingleNum+=recBuf.charAt(i);
    } else {
      bufSingleNum.trim();
      rawData[rawPos++]=bufSingleNum.toInt();
      bufSingleNum="";
    }
  }

  irrecv.disableIRIn();  // Stop the receiver
  irsend.sendRaw(rawData, numEle, 38); 
  irrecv.enableIRIn();  // Start the receiver
}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Create a random client ID
    String clientId = String("ESP8266" + room_name);
    //clientId += String(random(0xffff), HEX);
    // Attempt to connect
    if (client.connect(clientId.c_str())) {
      Serial.println("connected");
      // Once connected, publish an announcement...
      client.publish(room_name.c_str(), "Connected");
      // ... and resubscribe
      client.subscribe(String(room_name + "/SendIR").c_str());
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

void setup() {
  pinMode(BUILTIN_LED, OUTPUT);     // Initialize the BUILTIN_LED pin as an output
  Serial.begin(kBaudRate);
  setup_wifi();
  client.setBufferSize(4096);
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);

//    OTAwifi();  // start default wifi (previously saved on the ESP) for OTA
#if defined(ESP8266)
  Serial.begin(kBaudRate, SERIAL_8N1, SERIAL_TX_ONLY);
#else  // ESP8266
  Serial.begin(kBaudRate, SERIAL_8N1);
#endif  // ESP8266
  while (!Serial)  // Wait for the serial connection to be establised.
    delay(50);
  Serial.printf("\n" D_STR_IRRECVDUMP_STARTUP "\n", kRecvPin);
//  OTAinit();  // setup OTA handlers and show IP
#if DECODE_HASH
  // Ignore messages with less than minimum on or off pulses.
  irrecv.setUnknownThreshold(kMinUnknownSize);
#endif  // DECODE_HASH
  irrecv.enableIRIn();  // Start the receiver


  irsend.begin();
}


void loop() {

  if (!client.connected()) {
    reconnect();
  }
  client.loop();

/*  unsigned long now = millis();
  if (now - lastMsg > 2000) {
    lastMsg = now;
    ++value;
    snprintf (msg, MSG_BUFFER_SIZE, "hello world #%ld", value);
    Serial.print("Publish message: ");
    Serial.println(msg);
    client.publish("IRBedroomReceivedIR", msg);
  }
*/
    // Check if the IR code has been received.
  if (irrecv.decode(&results)) {
    // Display a crude timestamp.
    uint32_t now = millis();
    Serial.printf(D_STR_TIMESTAMP " : %06u.%03u\n", now / 1000, now % 1000);
    // Check if we got an IR message that was to big for our capture buffer.
    if (results.overflow)
      Serial.printf(D_WARN_BUFFERFULL "\n", kCaptureBufferSize);
    // Display the library version the message was captured with.
    Serial.println(D_STR_LIBRARY "   : v" _IRREMOTEESP8266_VERSION_ "\n");
    // Display the basic output of what we found.
    String theResult,theSrc;
    theResult=resultToHumanReadableBasic(&results);
    theSrc=resultToSourceCode(&results);
    Serial.println(theSrc.c_str());
    
    
    bool isPub = client.publish(String(room_name + "/ReceivedIR").c_str(), theSrc.c_str());
    if (isPub) 
      Serial.println("PUBLISHED");
    else
      Serial.println("PUBLISH FAILED");
    
  }


}